update nixpkgs

btcpayserver: 1.13.1 -> 1.13.5 clightning: 24.05 -> 24.08 lnd: 0.18.2-beta -> 0.18.3-beta nbxplorer: 2.5.2 -> 2.5.6
2024-09-14 19:12:35 +00:00
parent 901f1250fd
commit 2baff274c4
7 changed files with 208 additions and 27 deletions
@@ -0,0 +1,97 @@
+# Copied from nixpkgs revision 673d99f1406cb09b8eb6feab4743ebdf70046557
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  pythonOlder,
+
+  # build-system
+  hatch-vcs,
+  hatchling,
+  cmake,
+  ninja,
+
+  # dependencies
+  packaging,
+  pathspec,
+  exceptiongroup,
+
+  # tests
+  build,
+  cattrs,
+  numpy,
+  pybind11,
+  pytest-subprocess,
+  pytestCheckHook,
+  setuptools,
+  tomli,
+  virtualenv,
+  wheel,
+}:
+
+buildPythonPackage rec {
+  pname = "scikit-build-core";
+  version = "0.10.5";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "scikit-build";
+    repo = "scikit-build-core";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-hpwXEWPofgMT4ua2tZI1mtGbaBkT2XPBd6QL8xTi1A0=";
+  };
+
+  postPatch = lib.optionalString (pythonOlder "3.11") ''
+    substituteInPlace pyproject.toml \
+      --replace-fail '"error",' '"error", "ignore::UserWarning",'
+  '';
+
+  build-system = [
+    hatch-vcs
+    hatchling
+  ];
+
+  dependencies =
+    [
+      packaging
+      pathspec
+    ]
+    ++ lib.optionals (pythonOlder "3.11") [
+      exceptiongroup
+      tomli
+    ];
+
+  nativeCheckInputs = [
+    build
+    cattrs
+    cmake
+    ninja
+    numpy
+    pybind11
+    pytest-subprocess
+    pytestCheckHook
+    setuptools
+    virtualenv
+    wheel
+  ];
+
+  # cmake is only used for tests
+  dontUseCmakeConfigure = true;
+
+  pytestFlagsArray = [ "-m 'not isolated and not network'" ];
+
+  disabledTestPaths = [
+    # store permissions issue in Nix:
+    "tests/test_editable.py"
+  ];
+
+  pythonImportsCheck = [ "scikit_build_core" ];
+
+  meta = with lib; {
+    description = "Next generation Python CMake adaptor and Python API for plugins";
+    homepage = "https://github.com/scikit-build/scikit-build-core";
+    changelog = "https://github.com/scikit-build/scikit-build-core/releases/tag/v${version}";
+    license = with licenses; [ asl20 ];
+    maintainers = with maintainers; [ veprbl ];
+  };
+}